Image statistics

Authors: Robert Haase, Daniela Vorkel, April 2020

Source

This macro shows how to retrieve basic statistics from images.

// get test data
run("Blobs (25K)");
run("Invert LUT");
input = getTitle();

Initialize GPU

and push image data to GPU memory:

run("CLIJ2 Macro Extensions", "cl_device=");
Ext.CLIJ2_clear();

// push data to GPU
Ext.CLIJ2_push(input);

// clean up ImageJ
run("Close All");

Image properties

In order to read out properties like image size, we get all dimensions by one call. CLIJ does not take pixel or voxel into account, because there are no physical units defined in CLIJ.

Ext.CLIJ2_getDimensions(input, width, height, depth);

print("Image width: " + width);
print("Image height: " + height);
print("Image depth: " + depth);

> Image width: 256
> Image height: 254
> Image depth: 1

Image statistics

We can derive basic statistics from images, parameter by parameter.

Ext.CLIJ2_getSumOfAllPixels(input, sum_of_all_pixels);
Ext.CLIJ2_getMinimumOfAllPixels(input, min_of_all_pixels);
Ext.CLIJ2_getMaximumOfAllPixels(input, max_of_all_pixels);
Ext.CLIJ2_getMeanOfAllPixels(input, mean_of_all_pixels);

print("Sum: " + sum_of_all_pixels);
print("Min: " + min_of_all_pixels);
print("Max: " + max_of_all_pixels);
print("Mean: " + mean_of_all_pixels);

> Sum: 6714936
> Min: 8
> Max: 248
> Mean: 103.2686

Detailed statistics

More detailed statistics can be done by this method. Note: an empty table will be handed over.

Ext.CLIJ2_statisticsOfImage(input);

At the end of the macro, clean up.